蜂窝日常

VBA-Web | VBA-Web (vba-tools.github.io)

大神的库，好好学习

下载

找了半天

Option Explicit

'***********************************************************************************************
'   * Please leave any Trademarks or Credits in place.
'   *
'   * ACKNOWLEDGEMENT TO CONTRIBUTORS :
'   *       STEPHEN BULLEN, 15 November 1998 - original PastPicture code
'   *       G HUDSON, 5 April 2010 - Pause Function
'   *       LUTZ GENTKOW, 23 July 2011 - Alt + PrtScrn
'   *       PAUL FRANCIS, 11 April 2013 - Putting all pieces together, bridging the 32 bit and 64 bit version.
'   *       CHRIS O, 12 April 2013 - Code suggestion to work on older versions of Access.
'   *
'   * DESCRIPTION: Creates a standard Picture object from whatever is on the clipboard.
'   *              This object is then saved to a location on the disc. Please note, this
'   *              can also be assigned to (for example) and Image control on a userform.
'   *
'   * The code requires a reference to the "OLE Automation" type library.
'   *
'   * The code in this module has been derived from a number of sources
'   * discovered on MSDN, Access World Forum, VBForums.
'   *
'   * To use it, just copy this module into your project, then you can use:
'   * SaveClip2Bit("C:\Pics\Sample.bmp") or  SaveClip2Bit ("D:\TEST.JPG")
'   * to save this to a location on the Disc.
'   * (Or)
'   * Set ImageControl.Image = PastePicture
'   * to paste a picture of whatever is on the clipboard into a standard image control.
'   *
'   * PROCEDURES:
'   *   PastePicture  :   The entry point for 'Setting' the Image
'   *   CreatePicture :   Private function to convert a bitmap or metafile handle to an OLE reference
'   *   fnOLEError    :   Get the error text for an OLE error code
'   *   SaveClip2Bit  :   The entry point for 'Saving' the Image, calls for PastePicture
'   *   AltPrintScreen:   Performs the automation of Alt + PrtScrn, for getting the Active Window.
'   *   Pause         :   Makes the program wait, to make sure proper screen capture takes place.
'**************************************************************************************************
 
'Declare a UDT to store a GUID for the IPicture OLE Interface
Private Type GUID
    Data1 As Long
    Data2 As Integer
    Data3 As Integer
    Data4(0 To 7) As Byte
End Type
 
'Declare a UDT to store the bitmap information
Private Type uPicDesc
    Size As Long
    Type As Long
    hPic As Long
    hPal As Long
End Type
 
'Windows API Function Declarations
#If Win64 = 1 And VBA7 = 1 Then
     
    'Does the clipboard contain a bitmap/metafile?
    Private Declare PtrSafe Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Integer) As Long
     
    'Open the clipboard to read
    Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
     
    'Get a pointer to the bitmap/metafile
    Private Declare PtrSafe Function GetClipboardData Lib "user32" (ByVal wFormat As Integer) As Long
     
    'Close the clipboard
    Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long
     
    'Convert the handle into an OLE IPicture interface.
    Private Declare PtrSafe Function OleCreatePictureIndirect Lib "oleaut32.dll" (PicDesc As uPicDesc, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long
     
    'Create our own copy of the metafile, so it doesn't get wiped out by subsequent clipboard updates.
    Declare PtrSafe Function CopyEnhMetaFile Lib "gdi32" Alias "CopyEnhMetaFileA" (ByVal hemfSrc As Long, ByVal lpszFile As String) As Long
     
    'Create our own copy of the bitmap, so it doesn't get wiped out by subsequent clipboard updates.
    Declare PtrSafe Function CopyImage Lib "user32" (ByVal handle As Long, ByVal un1 As Long, ByVal n1 As Long, ByVal n2 As Long, ByVal un2 As Long) As Long
     
    'Uses the Keyboard simulation
    Private Declare PtrSafe Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
 
#Else
 
    'Does the clipboard contain a bitmap/metafile?
    Private Declare Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Integer) As Long
     
    'Open the clipboard to read
    Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
     
    'Get a pointer to the bitmap/metafile
    Private Declare Function GetClipboardData Lib "user32" (ByVal wFormat As Integer) As Long
     
    'Close the clipboard
    Private Declare Function CloseClipboard Lib "user32" () As Long
     
    'Convert the handle into an OLE IPicture interface.
    Private Declare Function OleCreatePictureIndirect Lib "oleaut32.dll" (PicDesc As uPicDesc, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long
     
    'Create our own copy of the metafile, so it doesn't get wiped out by subsequent clipboard updates.
    Declare Function CopyEnhMetaFile Lib "gdi32" Alias "CopyEnhMetaFileA" (ByVal hemfSrc As Long, ByVal lpszFile As String) As Long
     
    'Create our own copy of the bitmap, so it doesn't get wiped out by subsequent clipboard updates.
    Declare Function CopyImage Lib "user32" (ByVal handle As Long, ByVal un1 As Long, ByVal n1 As Long, ByVal n2 As Long, ByVal un2 As Long) As Long
     
    'Uses the Keyboard simulation
    Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
 
#End If
   
'The API format types we're interested in
Const CF_BITMAP = 2
Const CF_PALETTE = 9
Const CF_ENHMETAFILE = 14
Const IMAGE_BITMAP = 0
Const LR_COPYRETURNORG = &H4
 
Private Const KEYEVENTF_KEYUP = &H2
Private Const VK_SNAPSHOT = &H2C
Private Const VK_MENU = &H12
 
' Subroutine    : AltPrintScreen
' Purpose       : Capture the Active window, and places on the Clipboard.
 
Sub AltPrintScreen()
    keybd_event VK_MENU, 0, 0, 0
    keybd_event VK_SNAPSHOT, 0, 0, 0
    keybd_event VK_SNAPSHOT, 0, KEYEVENTF_KEYUP, 0
    keybd_event VK_MENU, 0, KEYEVENTF_KEYUP, 0
End Sub
 
' Subroutine    : PastePicture
' Purpose       : Get a Picture object showing whatever's on the clipboard.
 
Function PastePicture() As IPicture
    'Some pointers
    Dim h As Long, hPtr As Long, hPal As Long, lPicType As Long, hCopy As Long
 
    'Check if the clipboard contains the required format
    If IsClipboardFormatAvailable(CF_BITMAP) Then
        'Get access to the clipboard
        h = OpenClipboard(0&)
        If h > 0 Then
            'Get a handle to the image data
            hPtr = GetClipboardData(CF_BITMAP)
 
            hCopy = CopyImage(hPtr, IMAGE_BITMAP, 0, 0, LR_COPYRETURNORG)
 
            'Release the clipboard to other programs
            h = CloseClipboard
            'If we got a handle to the image, convert it into a Picture object and return it
            If hPtr <> 0 Then Set PastePicture = CreatePicture(hCopy, 0, CF_BITMAP)
        End If
    End If
End Function
 
 
' Subroutine    : CreatePicture
' Purpose       : Converts a image (and palette) handle into a Picture object.
' NOTE          : Requires a reference to the "OLE Automation" type library
 
Private Function CreatePicture(ByVal hPic As Long, ByVal hPal As Long, ByVal lPicType) As IPicture
    ' IPicture requires a reference to "OLE Automation"
    Dim r As Long, uPicInfo As uPicDesc, IID_IDispatch As GUID, IPic As IPicture
    'OLE Picture types
    Const PICTYPE_BITMAP = 1
    Const PICTYPE_ENHMETAFILE = 4
    ' Create the Interface GUID (for the IPicture interface)
    With IID_IDispatch
        .Data1 = &H7BF80980
        .Data2 = &HBF32
        .Data3 = &H101A
        .Data4(0) = &H8B
        .Data4(1) = &HBB
        .Data4(2) = &H0
        .Data4(3) = &HAA
        .Data4(4) = &H0
        .Data4(5) = &H30
        .Data4(6) = &HC
        .Data4(7) = &HAB
    End With
    ' Fill uPicInfo with necessary parts.
 
    With uPicInfo
        .Size = Len(uPicInfo) ' Length of structure.
        .Type = PICTYPE_BITMAP ' Type of Picture
        .hPic = hPic ' Handle to image.
        .hPal = hPal ' Handle to palette (if bitmap).
    End With
 
    ' Create the Picture object.
    r = OleCreatePictureIndirect(uPicInfo, IID_IDispatch, True, IPic)
 
    ' If an error occurred, show the description
    If r <> 0 Then Debug.Print "Create Picture: " & fnOLEError(r)
 
    ' Return the new Picture object.
    Set CreatePicture = IPic
End Function
 
 
' Subroutine    : fnOLEError
' Purpose       : Gets the message text for standard OLE errors
 
Private Function fnOLEError(lErrNum As Long) As String
    'OLECreatePictureIndirect return values
    Const E_ABORT = &H80004004
    Const E_ACCESSDENIED = &H80070005
    Const E_FAIL = &H80004005
    Const E_HANDLE = &H80070006
    Const E_INVALIDARG = &H80070057
    Const E_NOINTERFACE = &H80004002
    Const E_NOTIMPL = &H80004001
    Const E_OUTOFMEMORY = &H8007000E
    Const E_POINTER = &H80004003
    Const E_UNEXPECTED = &H8000FFFF
    Const S_OK = &H0
 
    Select Case lErrNum
        Case E_ABORT
            fnOLEError = " Aborted"
        Case E_ACCESSDENIED
            fnOLEError = " Access Denied"
        Case E_FAIL
            fnOLEError = " General Failure"
        Case E_HANDLE
            fnOLEError = " Bad/Missing Handle"
        Case E_INVALIDARG
            fnOLEError = " Invalid Argument"
        Case E_NOINTERFACE
            fnOLEError = " No Interface"
        Case E_NOTIMPL
            fnOLEError = " Not Implemented"
        Case E_OUTOFMEMORY
            fnOLEError = " Out of Memory"
        Case E_POINTER
            fnOLEError = " Invalid Pointer"
        Case E_UNEXPECTED
            fnOLEError = " Unknown Error"
        Case S_OK
            fnOLEError = " Success!"
    End Select
End Function
 
' Routine   : SaveClip2Bit
' Purpose   : Saves Picture object to desired location.
' Arguments : Path to save the file
 
Public Sub SaveClip2Bit(savePath As String)
On Error GoTo errHandler:
    AltPrintScreen
    Pause (3)
    SavePicture PastePicture, savePath
errExit:
        Exit Sub
errHandler:
    Debug.Print "Save Picture: (" & Err.Number & ") - " & Err.Description
    Resume errExit
End Sub
 
' Routine   : Pause
' Purpose   : Gives a short interval for proper image capture.
' Arguments : Seconds to wait.
 
Public Function Pause(NumberOfSeconds As Variant)
On Error GoTo Err_Pause
    Dim PauseTime As Variant, start As Variant
    PauseTime = NumberOfSeconds
    start = Timer
    Do While Timer < start + PauseTime
        DoEvents
    Loop
Exit_Pause:
    Exit Function
Err_Pause:
    MsgBox Err.Number & " - " & Err.Description, vbCritical, "Pause()"
    Resume Exit_Pause
End Function

Function isVIN(VIN As String) As Boolean
    ' 检查车架号VIN是否符合标准
    ' 参数：
    '   VIN：需要检查的车架号字符串
    ' 返回值:
    ' Boolean: 正确返回True，错误返回False
    If TypeName(VIN) <> "String" Then ' 如果不是文本，退出检查
        isVIN = False
        Exit Function
    End If
    
    If Len(Trim(VIN)) <> 17 Then ' 如果没有17位，退出检查
        isVIN = False
        Exit Function
    End If

    VIN = UCase(VIN)
    Dim RE As Object
    Set RE = CreateObject("VBScript.RegExp")
    RE.Pattern = "^[A-HJ-NPR-Z\d]{8}[X\d][A-HJ-NPR-Z\d]{3}\d{5}$"

    If Not RE.Test(VIN) Then ' 如果不符合正则要求，退出检查
        isVIN = False
        Exit Function
    End If

    Dim cOT As Object
    Set cOT = CreateObject("Scripting.Dictionary")
    cOT.Add "0", 0
    cOT.Add "1", 1
    cOT.Add "2", 2
    cOT.Add "3", 3
    cOT.Add "4", 4
    cOT.Add "5", 5
    cOT.Add "6", 6
    cOT.Add "7", 7
    cOT.Add "8", 8
    cOT.Add "9", 9
    cOT.Add "A", 1
    cOT.Add "B", 2
    cOT.Add "C", 3
    cOT.Add "D", 4
    cOT.Add "E", 5
    cOT.Add "F", 6
    cOT.Add "G", 7
    cOT.Add "H", 8
    cOT.Add "J", 1
    cOT.Add "K", 2
    cOT.Add "L", 3
    cOT.Add "M", 4
    cOT.Add "N", 5
    cOT.Add "P", 7
    cOT.Add "R", 9
    cOT.Add "S", 2
    cOT.Add "T", 3
    cOT.Add "U", 4
    cOT.Add "V", 5
    cOT.Add "W", 6
    cOT.Add "X", 7
    cOT.Add "Y", 8
    cOT.Add "Z", 9

    Dim xWT As Variant
    xWT = Array(8, 7, 6, 5, 4, 3, 2, 10, 0, 9, 8, 7, 6, 5, 4, 3, 2)

    Dim sum As Long
    For i = 1 To 17
        sum = sum + cOT(Mid(VIN, i, 1)) * xWT(i - 1)
    Next i

    Dim cT As Variant
    cT = Array("0", "1", "2", "3", "4", "5", "6", "7", "8", "9", "X")

    isVIN = (cT(sum Mod 11) = Mid(VIN, 9, 1))

End Function

所有的xml图标资源库

BERT | ImageMSO List Reference (bert-toolkit.com)

所有的idMso功能

因经常接触加密Excel数据文件，密码又难记，所以有此办法

复制下面代码到记事本，另存为 【快捷打开.vbs】 文件

Set args = Wscript.Arguments
FilePath = args(0)
Const Pwd = "xxxxx" '事先知道的Excel文件密码，是打开密码，不是工作簿密码
Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = True
objExcel.WorkBooks.Open FilePath,0,True,,Pwd
tittle = "JBH Only"
objExcel.Caption = tittle
set ws=createobject("wscript.shell")
ws.appactivate tittle
ws.sendkeys "{enter}"
ws.quit
set ws = nothing
set args = nothing

参见

参考下面范例

Sub Xpath定位() 'MSXML2.DOMDocument.6.0
    Const str_Html As String = _
        "<div id = ""outside"">" & _
            "<div id =""box"">" & _
                "<div id = ""head"" class = ""color0"">AAA</div>" & _
                "<div id = ""body"" class = ""color1"">BBB</div>" & _
                "<div id = ""footer1"" class = ""color1"">" & _
                    "<div id = ""footer2"" class = ""color2"">CCC</div>" & _
                "</div>" & _
            "</div>" & _
        "</div>"
    Dim xmlDom As New MSXML2.DOMDocument60  '引用Microsoft xml,v6.0
'    Dim xmlDom As Object
'    Set xmlDom = CreateObject("Msxml2.DOMDocument.6.0")

    If Not xmlDom.LoadXML(str_Html) Then
        MsgBox xmlDom.parseError.reason
        Set xmlDom = Nothing
        Exit Sub
    End If
    Debug.Print xmlDom.SelectSingleNode("//div/ @ id").Text '根路径下div id
    Debug.Print xmlDom.SelectSingleNode("//div/div/ @ id").Text
    Debug.Print xmlDom.SelectSingleNode("//div/div[ @ class = ""color1""]").Text
    Debug.Print xmlDom.SelectSingleNode("//div/div[ @ id=""body""]").Text
    Debug.Print xmlDom.SelectNodes("//div/div/@id")(0).Text
    Debug.Print xmlDom.SelectNodes("//div/div/@id")(2).Text
    Debug.Print xmlDom.SelectNodes("//div/div[@id=""footer2""]")(0).Text '只有一个结果
    Debug.Print xmlDom.SelectNodes("//div [@id=""box""] /div [@class=""color1"" ] ")(0).Text
    Debug.Print xmlDom.SelectNodes("//div/div/@id")(0).XML

    Set xmlDom = Nothing
End Sub

两种方式，一种需要本机Outlook配置好的，一种不需要，使用CDO

一、Outlook模式

该模式需要你电脑中有正常使用的Outlook，不是装了软件就可以了，要配置好正常能用

用例

Sub test()
    Set mm = New MailForOutlook
    s = mm.GenerateEmail("gnefnuy@qq.com", "主题：测试", "<b>加粗</b><br>测试", True)
End Sub

用例，VBA的环境是GB2312的，直接MD5中文字符出来的会与实际通用的UTF8字符数据不一致，所以要先转UTF8再MD5

Sub test()
    Dim f As New MD5
    Dim s As String
    s = "中文字"
    Debug.Print "ANSI:" & f.DigestStrToHexStr(s)
    Dim a() As Byte, b() As Byte
    a = s
    Debug.Print "GB2312:" & f.DigestByteToHexStr(a)
    Debug.Print "GB2312-UTF8:" & f.DigestByteToHexStr(Unicode_To_UTF8(a)) '这里的数据和网上在线MD5验证网站一致。
    b = StrConv(s, vbFromUnicode)
    Debug.Print "ANSI-UTF8:" & f.DigestByteToHexStr(Unicode_To_UTF8(b))
End Sub

国外

https://www.rondebruin.nl/index.htm  一个MVP，主要讲Ribbon功能